未知な結晶・液晶構造についてモデル構造・格子定数を組み立てたけど、そこから計算されるd値・反射位置は実際に得られたX線回折測定結果と一致しているの？どのようにモデル構造が正しいか検証すれば良いの？と困っている人も多いと思います。
そこで組み立てたモデル構造・格子定数がX線回折測定結果と矛盾がないか検証出来るように、格子定数からd値・反射位置をエクセルで計算する方法を、高校数学の内容で分かりやすく説明します！
目次
Excel用計算式
下記表の全範囲を選択・コピーし、ExcelのA1セルにペーストしてください。格子定数・ミラー指数(hkl)を入力することで、d値・反射位置の計算結果を得られます（自分好みにアレンジして使用下さい）。各計算式の算出方法については次の項目で説明します。
※格子定数がnm表記である事に注意下さい。
| （1）格子定数 | |||
| a(nm) | 1 | α(°) | 90 |
| b(nm) | 2 | β(°) | 90 |
| c(nm) | 3 | γ(°) | 90 |
| （2）実格子ベクトルへの変換 | |||
| x成分 | y成分 | z成分 | |
| aﾍﾞｸﾄﾙ | =B2 | 0 | 0 |
| bﾍﾞｸﾄﾙ | =B3*COS(D4/180*PI()) | =B3*SIN(D4/180*PI()) | 0 |
| cﾍﾞｸﾄﾙ | =B4*COS(D3/180*PI()) | =B4/SIN(D4/180*PI())*(COS(D2/180*PI())-COS(D3/180*PI())*COS(D4/180*PI())) | =(B4^2*(SIN(D3/180*PI()))^2-C9^2)^0.5 |
| （3）逆格子ベクトルへの変換 | |||
| b×c | =C8*D9 | =-B8*D9 | =B8*C9-C8*B9 |
| c×a | 0 | =D9*B7 | =-C9*B7 |
| a×b | 0 | 0 | =B7*C8 |
| ※a・b×c=b・c×a=c・a×b=B7*C8*D9 | |||
| a*ﾍﾞｸﾄﾙ | =B11/(B7*C8*D9) | =C11/(B7*C8*D9) | =D11/(B7*C8*D9) |
| b*ﾍﾞｸﾄﾙ | 0 | =C12/(B7*C8*D9) | =D12/(B7*C8*D9) |
| c*ﾍﾞｸﾄﾙ | 0 | 0 | =D13/(B7*C8*D9) |
| （4）d値の算出 | |||
| h | 1 | ||
| k | 0 | ||
| l | 0 | ||
| x成分 | y成分 | z成分 | |
| d*hkl | =B19*B15+B20*B16+B21*B17 | =B19*C15+B20*C16+B21*C17 | =B19*D15+B20*D16+B21*D17 |
| dhkl(nm) | =1/(B24^2+C24^2+D24^2)^0.5 | ||
| （5）反射位置の算出 | |||
| エワルド球と逆格子点の交点をP、点Pをz軸方向からxy平面に投影した点をP’とする。 | |||
| λ(nm) | 0.15418 | ||
| ・z軸回りに制限ない場合（例えば、繊維軸がz軸） | |||
| x成分 | y成分 | z成分 | |
| OPﾍﾞｸﾄﾙ | =-B28/2*(B24^2+C24^2+D24^2) |
=(B24^2+C24^2-B31^2)^0.5 |
=D24 |
| X線回折像で出現する位置(赤道線方向からの角度)(°) | =ACOS((B31^2+C31^2)/((B31^2+C31^2+D31^2)^0.5*(B31^2+C31^2)^0.5))/PI()*180 | ||
| ・y軸回りに制限ない場合（例えば、繊維軸がy軸） | |||
| x成分 | y成分 | z成分 | |
| OPﾍﾞｸﾄﾙ | =-B28/2*(B24^2+C24^2+D24^2) |
=C24 |
=(B24^2+C24^2-B36^2)^0.5 |
| X線回折像で出現する位置(赤道線方向からの角度)(°) | =ACOS((B36^2+C36^2)/((B36^2+C36^2+D36^2)^0.5*(B36^2+C36^2)^0.5))/PI()*180 | ||
各計算式の説明
数式は複雑に見えるかもしれませんが、使用している内容は全て高校数学で習うものです。難しく考えずに理解していきましょう！
X線回折測定結果からモデル構造・格子定数を組み立てる方法については「【X線回折測定法】未知な結晶・液晶構造のわかりやすい解析方法」を参照ください。
１．格子定数
・X線回折測定結果からモデル構造・格子定数a,b,c,\(\alpha\),\(\beta\),\(\gamma\)を組み立てる。
・計算を簡単にするために、x軸上に\(\vec{a}\)を、xy平面上に\(\vec{b}\)を設置する。
２．実格子ベクトルへの変換
・\(\vec{a}\)、\(\vec{b}\)は次式で示される。
$$ \vec{a} = (\left|\vec{a} \right|,0,0)$$
$$ \vec{b} = (\left|\vec{b} \right|\cos \gamma,\left|\vec{b} \right|\sin \gamma,0)$$
・\(\vec{c}\)は原点Oを始点にもち（1）aベクトルから\(\beta\)傾いた円と、（2）bベクトルから\(\alpha\)傾いた円の交点を終点にもつ。
（1）aベクトルから\(\beta\)傾いた円①
（2）bベクトルから\(\alpha\)傾いた円③
・まず、モデル構造全体をz軸回りにx軸からy軸の方向に(90-\(\gamma\))°回転させる。すると\(\vec{b}\)から\(\alpha\)傾いた円②は次式で示される。
・モデル構造全体をz軸回りにx軸からy軸の方向に-(90-\(\gamma\))°回転させ元の状態に戻すと、円②は回転行列を用いて円③の方程式で示される。
・円①と円③の方程式を解くと\(\vec{c}\)が得られる。
$$ \vec{c} =
\begin{pmatrix}
c \cos \beta \\
\frac{c}{\sin \gamma} (\cos \alpha – \cos \beta \cos \gamma) \\
\sqrt{c^2 \sin^2 \beta – y^2}
\end{pmatrix}
$$
３．逆格子ベクトルへの変換
・「【X線回折測定法】初心者向け・簡単に分かる原理と構造解析方法」で説明した次式を用いて、実格子ベクトルを逆格子ベクトルに変換する。
$$ \vec{a^*} = \frac{\vec{b} \times \vec{c}}{\vec{a} \cdot \vec{b} \times \vec{c}} , \vec{b^*} = \frac{\vec{c} \times \vec{a}}{\vec{b} \cdot \vec{c} \times \vec{a}} , \vec{c^*} = \frac{\vec{a} \times \vec{b}}{\vec{c} \cdot \vec{b} \times \vec{c}} $$
４．d値の算出
・逆格子ベクトルはミラー指数(hkl)を用いて次式で示される。
$$ \vec{d_{hkl}^*} = h\vec{a^*} + k\vec{b^*} + l\vec{c^*} $$
・次式を用いてd値を算出する。
$$ \left|\vec{d_{hkl}} \right| = \frac{1}{\left|\vec{d_{hkl}^*}\right|} $$
５．反射位置の算出
・\(\vec{d_{hkl}^*}\)=(x’,y’,z’)、エワルド球と逆格子点の交点をP、点Pをz軸方向からxy平面に投影した点をP’とする。
（1）モデル構造がz軸回りに制限がない場合（例えば繊維試料で繊維軸がz軸の場合）
・z軸回りに制限がないため逆格子点は円④上に存在する。
・円④とエワルド球の方程式を解くと\(\vec{OP}\)が得られる。
$$ \vec{OP} =
\begin{pmatrix}
– \frac{\lambda}{2} (x’^2 + y’^2 + z’^2)\\
\sqrt{x’^2 + y’^2 – x^2} \\
z’
\end{pmatrix}
$$
・内積の公式を利用し次式より、X線回折像上に反射が出現する位置(赤道線方向からの角度)\(\phi\)(°)が算出される。
$$\phi = \displaystyle \arccos \frac{\vec{OP} \cdot \vec{OP’}}{\left|\vec{OP}\right| \left|\vec{OP’}\right|}$$
（2）モデル構造がy軸回りに制限がない場合（例えば繊維試料で繊維軸がy軸の場合）
・y軸回りに制限がないため逆格子点は円⑤の方程式上に存在する。
・円⑤とエワルド球の方程式を解くと\(\vec{OP}\)が得られる。
$$ \vec{OP} =
\begin{pmatrix}
– \frac{\lambda}{2} (x’^2 + y’^2 + z’^2)\\
y’ \\
\sqrt{x’^2 + z’^2 – x^2}
\end{pmatrix}
$$
・同様にX線回折像上に反射が出現する位置(赤道線方向からの角度)\(\phi\)(°)が算出される。
X線回折測定を理解するためにおすすめの本
X線回折測定は非常に有力な評価方法であり、より正しく詳細に原理を理解することで、らせん構造や電子密度分布などに関する情報を得ることができます。
ここで紹介した原理や、もっと詳細に勉強したいという方には「X線構造解析―原子の配列を決める（著者：早稲田嘉夫、松原英一郎）」を強くおすすめします。
X線回折測定の基本から応用的な原理について詳細に丁寧に説明しており、この本1冊で十分にX線回折測定に関する知識を十分に付けることが出来ます。